Do you configure your AI content filters and document the settings?

Azure OpenAI models come with a content filter that blocks harmful prompts and responses. It is on by default, so most teams never look at it. Then a real customer question gets blocked, someone changes a setting by hand in the portal, and nobody can say what the app filters any more.

That's why you should choose the filter settings for your app on purpose, and keep them in the repo.

Know what the default blocks

Figure: The default filter for text models

Fit the filter to your users

• Stricter or looser - For each of the four content categories you choose where blocking starts: low, medium or high severity. Prompts and responses are set separately. Turning a filter off needs Microsoft's approval
• Apps that read documents - Turn on the check for attacks hidden in documents, emails and web pages
• Blocked requests - A blocked prompt comes back as an HTTP 400 error, and a blocked response has finish_reason set to content_filter. Show the user a clear message for both

Keep the settings where the team can review them

Define the filter in Bicep and name it on the model deployment. A change to what the app blocks then goes through a pull request, like any other Azure resource.

resource chat 'Microsoft.CognitiveServices/accounts/deployments@2024-10-01' = {
  parent: account
  name: 'support-chat'
  properties: {
    model: chatModel
    // no filter named here
  }
}

❌ Figure: Bad example - The deployment names no filter. The settings live only in the portal, so nobody can review a change

resource filter 'Microsoft.CognitiveServices/accounts/raiPolicies@2024-10-01' = {
  parent: account
  name: 'northwind-support-chat'
  properties: {
    basePolicyName: 'Microsoft.Default'
    contentFilters: [
      // Stricter than the default (Medium): the chat is open to the public
      { name: 'Hate', source: 'Prompt', severityThreshold: 'Low', blocking: true, enabled: true }
      { name: 'Hate', source: 'Completion', severityThreshold: 'Low', blocking: true, enabled: true }
      // The same two lines for Sexual, Violence and Selfharm
    ]
  }
}

resource chat 'Microsoft.CognitiveServices/accounts/deployments@2024-10-01' = {
  parent: account
  name: 'support-chat'
  properties: {
    model: chatModel
    raiPolicyName: filter.name
  }
}

✅ Figure: Good example - The filter is in Bicep with the reason beside it, and the deployment names it